Rangery

Scroll down for Multi-Morph Macro

//Rangery by Noivad
f3 call Shieldstone //modify this to your chosen hotkey
shift-f3 call UnShieldstone //modify this to your chosen hotkey

f4 call Heartwood //modify these to your chosen hotkey/etc
wheelup call Heartwood //works with trackpads that support 2 finger touch up

wheeldown call Heartslow //works with trackpads that support 2 finger touch down

f6 call reflection //modify this to your chosen hotkey

set shso 0

Shieldstone
{
if shso == 1
	goto OFF
end if

if @my.finger_item == "Shieldstone"
	goto ON
end if

label equip
"/equip shieldstone\r"

label ON
"/useitem finger\r"
pause 1

label CHECK
if @env.textLog >= "Your Shieldstone goes inert"
	goto equip
end if

label TIMER
pause 1
setglobal shso 1
goto END

label OFF
"/useitem finger /cancel\r"
setglobal shso 0
label END
}

UnShieldstone
{
"/unequip finger\r"
setglobal shso 0
}

Heartwood
{
if @my.left_item != "Heartwood Charm"
	"/equip heartwood\r"
end if
"/useitem left\r"
}

Heartslow
{
	"/useitem heartwood charm /slow\r"
}
 
"/judge" call judge

judge
{
"/useitem belt /judge " @text "\r"
}

"/reflect" call reflection

reflection
{
"/useitem belt /reflect\r"
}

"/be"
{
"/usei belt /befriend\r"
"/pose bless\r"
}

"/con"
{
"/usei belt /control\r"
"/pose sal\r"
}

"/dis"
{
"dismissing\r"
"/pose surprised\r"
pause 3
"/usei belt /dismiss\r"
}

"/unm" call unmorph

unmorph
{
	"/useitem /belt /return\r"
}

Multi-Creature Morph Macro

I recommend mapping the increment/decrement to your scroll wheel. This is usable with Rangery.txt above or scroll down for a simple 1 creature macro

/**MultiMorph v1.1**/
f8 call incrementMorph 
f9 call decrementMorph
click3 call morph
f11	call morph

set morphed 0 //[DO NOT ALTER] toggle used to tell if you are morphed "1" or not "0" 
set mindex 1 // "Morph Index"
set verbose 1
set totalMorphs 1 //**see note

/*CHANGE ME*/
set morph[1] "Sky Bison" //change and add your morphs
set morph[2] "Darshak Assassin"
set morph[3] ""
set morph[4] ""
set morph[5] ""
set morph[6] ""

morph
{
	if morphed == 0
		"/useitem belt /shape " morph[mindex] "\r"
		setglobal morphed 1
	else
		"/useitem belt /return \r"
		setglobal morphed 0
	end if
}

incrementMorph
{
if mindex == totalMorphs
	setglobal mindex 1
else 
	setglobal mindex + 1
end if
call whichMorph
}

decrementMorph
{
if mindex == 1
	setglobal mindex totalMorphs
else 
	setglobal mindex - 1
end if
call whichMorph
}

whichMorph
{
if verbose == 1
	message "*Morph Selected:" morph[mindex]
end if
}

**setting totalMorphs to 1 means it will never set the morph to Darshak Assassin below, so you can include creatures your working on morphs for and edit this number when you get them

• note for all Morph Macros listed: morph state detection fails if falls & spirit runouts are not scanned for. you can use scanner.txt to avoid this or add

if @textLog < "you return to your normal"
     set morphed 0
end if

Simple Morph Macro

just change *creature name* to the name of your creature

//Alternate Simple 1 creature morph
click3 call morph
f11	call morph

set morphed 0
morph
{
	if morphed == 0
		"/useitem belt /shape *creature name* \r" //insert creature name
		setglobal morphed 1
	else
		"/useitem belt /return \r"
		setglobal morphed 0
	end if
}