View source for Rangery

==About the Ranger Macros==
This set of macros ''(except the Simple Morph Macro)'' are the ones Noivad uses for his ranger abilities. You are free to modify these as you see fit. the triggers in ''<trigger>'' call ''<macro>'' are all modifiable without affecting the macros. So if you wanted to change the shieldstone macro from F3 to escape, you’d edit the first line to say '''escape call toggleShieldstone'''. 
*Scroll down for Multi-Morph Macro
==Rangery==
 //Rangery by Noivad
 f3 call toggleShieldstone //modify this to your chosen hotkey
 shift-f3 call UnShieldstone //modify this to your chosen hotkey
 
 f4 call Heartwood //modify these to your chosen hotkey/etc
 wheelup call Heartwood //works with trackpads that support 2 finger touch up
 
 wheeldown call Heartslow //works with trackpads that support 2 finger touch down
 
 f6 call reflection //modify this to your chosen hotkey
 
 set shso 0
 
  toggleShieldstone //v1.1
 {
 	if @my.finger_item == "Shieldstone" //skips equip phase if true
 	     goto ON
 	end if
 
 	label equip
 	"/equip shieldstone\r"
 
 	label ON
 	"/useitem shieldstone\r"
 	pause 1
 
 	label CHECK //Checks for Shieldstone failures …
 	if @env.textLog >= "Your Shieldstone goes inert"
 	     pause 6
 	     goto equip //…if so equips backup (if you have 1)
 	end if
 }
 
 UnShieldstone
 {
 "/unequip finger\r"
 setglobal shso 0
 }
 
 Heartwood
 {
 if @my.left_item != "Heartwood Charm"
 	"/equip heartwood\r"
 end if
 "/useitem left\r"
 }
 
 Heartslow
 {
 	"/useitem heartwood charm /slow\r"
 }
  
 "/judge" call judge
 
 judge
 {
 "/useitem belt /judge " @text "\r"
 }
 
 "/reflect" call reflection
 
 reflection
 {
 "/useitem belt /reflect\r"
 }
 
 "/be"
 {
 "/usei belt /befriend\r"
 "/pose bless\r"
 }
 
 "/con"
 {
 "/usei belt /control\r"
 "/pose sal\r"
 }
 
 "/dis"
 {
 "Dismissing in 3 seconds\r"
 pause 15
 "/pose surprised\r"
 "/useitem belt /dismiss\r"
 }
 
 "/unm" call unmorph
 
 unmorph
 {
 	"/useitem /belt /return\r"
 }

==Multi-Creature Morph Macro==

I recommend mapping the increment/decrement to your scroll wheel. This is usable with Rangery.txt above or scroll down for a simple 1 creature macro

 /**MultiMorph v1.1**/
 f8 call incrementMorph 
 f9 call decrementMorph
 click3 call morph
 f11	call morph
 
 set morphed 0 //[DO NOT ALTER] toggle used to tell if you are morphed "1" or not "0" 
 set mindex 1 // "Morph Index"
 set verbose 1 //change this to 0 if you don’t want the increment/decrement macros to tell you which creature you’ve selected to morph into ''(not recommended)''
 set totalMorphs 2 //**see note ''(total number of morphs you have)''
 set whichMorph0 ""
 /*CHANGE ME*/
 set morph[1] "Sky Bison" //change and add your morphs
 set morph[2] "Mistral Kestrel"
 set morph[3] ""
 set morph[4] ""
 set morph[5] ""
 set morph[6] ""
 //''Add more '''set morph[#]''' for additional morphs''
 
 morph
 {
 	if morph[mindex] != whichMorph0
 		"/useitem belt /shape " morph[mindex] "\r"
 		setglobal morphed 1
 		setglobal whichMorph0 morph[mindex]
 	else if morphed == 0
 		if @my.waist_item != "belt of the wild"
 		if @my.waist_item != ""
 			setglobal waistItem @my.waist_item
 		else 
 			set waistItem "belt of the wild"
 		end if
 			"/equip beltofthewild\r"
 		end if
 		"/useitem belt /shape " morph[mindex] "\r"
 		setglobal morphed 1
 		setglobal whichMorph0 morph[mindex]
 	
 	else
 		"/useitem belt /return \r"
 		setglobal morphed 0
 		if waistItem != ""
 			if waistItem != "belt of the wild"
 				"/equip " waistItem "\r"
 			end if
 		end if
 		set whichMorph0 0
 	end if
 } 
 
 incrementMorph
 {
 if mindex == totalMorphs
 	setglobal mindex 1
 else 
 	setglobal mindex + 1
 end if
 call whichMorph
 }
 
 decrementMorph
 {
 if mindex == 1
 	setglobal mindex totalMorphs
 else 
 	setglobal mindex - 1
 end if
 call whichMorph
 }
 
 whichMorph
 {
 if verbose == 1
 	message "*Morph Selected:" morph[mindex]
 end if
 }

''**setting totalMorphs to 1 means it will never set the morph to Mistral Kestral above and only morph into the Sky Bison, so you can include creatures your working on morphs for and edit this number when you get them'' In this case for both morphs, the correct number is 2.

*note for all Morph Macros listed:  morph state detection fails if falls & spirit runouts are not scanned for. you can use [[scanner.txt]] to avoid this or add the following to your text log scanning macro:
 if @textLog < "you return to your normal"
      setglobal morphed 0
 end if

==Simple Morph Macro==
just change *creature name* to the name of your creature
 //Alternate Simple 1 creature morph
 click3 call morph
 f11	call morph
 
 set morphed 0
 morph
 {
 	if morphed == 0
 		"/useitem belt /shape *creature name* \r" //insert creature name
 		setglobal morphed 1
 	else
 		"/useitem belt /return \r"
 		setglobal morphed 0
 	end if
 }